DECLARE @var NVARCHAR(MAX)
DECLARE @xml XML

SET @var = '1,2,3,4,5'

SET @xml = N'<root><r>' + REPLACE(@var,',','</r><r>') + '</r></root>'

SELECT [t].[value]('.','int') AS [Id]
FROM @xml.[nodes]('//root/r') AS [a]([t])
GO

Od verze SQL Server 2016 (compatibility level = 130) už naštěstí nemusíme podobný scénář absolvovat a stačí využití novou funkci pro parsování řetězců STRING_SPLIT():

DECLARE @var NVARCHAR(MAX)

SET @var = '1,2,3,4,5'

SELECT * FROM STRING_SPLIT(@var, ',')
GO

1. Extracting values using .nodes method and XPATH navigation

Sample XML:

DECLARE @XML XML

SET @XML = 
N'
<Rows xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" Description = "Test Description" User = "test_user">
   <Row RowId = "1">
      <Columns>
         <Column Name = "Col1" Value = "50"/>
      </Columns>
   </Row>
   <Row RowId = "2">
      <Columns>
         <Column Name = "Col1" Value = "70"/>
         <Column Name = "Col2" Value = "80"/>
         <Column Name = "Col3"/>
      </Columns>
   </Row>
</Rows>
'

Extract User and Description values from the root element:

SELECT 
    OneRow.value('@User', 'nvarchar(128)') [UserName],
    OneRow.value('@Description', 'nvarchar(1000)') [Description]
FROM @XML.nodes('/Rows') RowSet(OneRow)

Extract values from inner elements. See how CROSS APPLY is used there.

SELECT 
    OneRow.value('@RowId', 'VARCHAR(15)') RowId,
    Item.value('@Name', 'NVARCHAR(128)') ColumnName,
    Item.value('@Value', 'NVARCHAR(MAX)') Value
FROM @XML.nodes('/Rows/Row') RowSet(OneRow)
    CROSS APPLY OneRow.nodes('Columns/Column') Col(Item)

Na následujících příkladech si ukážeme, jak na to. Naplníme si testovací tabulku jednoduchými řetězci, které spojíme dohromady pomocí FOX XML PATH. V příkladu vidíme dva možné zápisy: se specifikací datových typů a zjednodušený:

CREATE TABLE dbo.SampleTable
(
    Value VARCHAR(100)
)
GO

INSERT INTO dbo.SampleTable
        ( Value )
    SELECT 'Value1' UNION ALL
    SELECT 'Value2' UNION ALL
    SELECT 'Value3' UNION ALL
    SELECT 'Value4'
GO

SELECT STUFF((SELECT ',' AS "text()", '''' AS "text()", Value AS "text()",  '''' AS "text()"
                 FROM dbo.SampleTable
                 FOR XML PATH(''))
             , 1, 1, '')
GO

-- returns: 'Value1','Value2','Value3','Value4'

SELECT STUFF((SELECT ','  + '''' + Value + '''' FROM dbo.SampleTable FOR XML PATH('')), 1, 1, '')
GO

-- returns: 'Value1','Value2','Value3','Value4'

V dalším příkladu vidíme použití stejné metody v rámci datového setu, kdy agregujeme názvy měst pro jednotlivé státy:

-- create sample tables
CREATE TABLE dbo.tblCountry
(
    Id INT NOT NULL IDENTITY(1,1) PRIMARY KEY,
    Name VARCHAR(100) NOT NULL
)

CREATE TABLE dbo.tblCity
(
    Id INT NOT NULL IDENTITY(1,1) PRIMARY KEY,
    CountryId INT NOT NULL,
    NAME VARCHAR(100) NOT NULL
)    

-- populate data
ALTER TABLE dbo.tblCity ADD CONSTRAINT FK_tblCity_tblCity FOREIGN KEY (CountryId) 
    REFERENCES dbo.tblCity (Id)

INSERT INTO dbo.tblCountry
    VALUES ('Germany'), ('Czech Republic')

INSERT INTO dbo.tblCity
    VALUES (1, 'Bonn'), (1, 'Berlin')

INSERT INTO dbo.tblCity
    VALUES (2, 'Praha'), (2, 'Brno'), (2, 'Ostrava')

-- review data
SELECT *
FROM dbo.tblCountry country
    INNER JOIN dbo.tblCity city ON city.CountryId = country.Id

-- put cities to inline CSV format
SELECT *
FROM dbo.tblCountry country
    CROSS APPLY (SELECT stuff((SELECT ', ' + c.Name 
                 FROM dbo.tblCity c 
                 WHERE c.CountryId = country.Id
                 FOR XML PATH('')), 1,2,'') Cities
                 FROM (SELECT 1 ID) a) city