SELECT
	[s].[name] [Schema_Name],
    [o].[name] AS [Object_Name],
	[o].[type_desc] [Object_Type],
	[ix].[name] AS [Primary_Key_Name],
    [ic].[index_column_id] AS [Column_Id],
    [c].[name] AS [Column_Name], 
	[ix].[type_desc] [Index_Type]
FROM [sys].[objects] [o]
	INNER JOIN [sys].[schemas] [s] ON [s].[schema_id] = [o].[schema_id]
    INNER JOIN [sys].[indexes] [ix] ON [o].[object_id] = [ix].[object_id] AND [ix].[is_primary_key] = 1
    INNER JOIN [sys].[index_columns] [ic] ON [ic].[object_id] = [ix].[object_id] AND [ic].[index_id] = [ix].[index_id]
    INNER JOIN [sys].[columns] [c] ON [ix].[object_id] = [c].[object_id] AND [c].[column_id] = [ic].[column_id]
ORDER BY [s].[name], [o].[name], [c].[Column_Id]

SELECT
		[a3].[name] AS [schemaname], [a2].[name] AS [tablename], [a1].[rows] AS [row_count],
		( [a1].[reserved] + ISNULL ([a4].[reserved], 0)) * 8 AS [reserved],
		[a1].[data] * 8 AS [data],
		( CASE
			WHEN ( [a1].[used] + ISNULL ([a4].[used], 0)) > [a1].[data] THEN
		( [a1].[used] + ISNULL ([a4].[used], 0)) - [a1].[data]
			ELSE
				0
		END ) * 8 AS [index_size],
		( CASE
			WHEN ( [a1].[reserved] + ISNULL ([a4].[reserved], 0)) > [a1].[used] THEN
		( [a1].[reserved] + ISNULL ([a4].[reserved], 0)) - [a1].[used]
			ELSE
				0
		END ) * 8 AS [unused]
FROM	(	SELECT	[ps].[object_id],
					SUM (CASE WHEN ( [ps].[index_id] < 2 ) THEN	[ps].[row_count] ELSE 0	END) AS [rows],
					SUM ([ps].[reserved_page_count]) AS [reserved],
					SUM (
						CASE
							WHEN ( [ps].[index_id] < 2 ) THEN
						( [ps].[in_row_data_page_count] + [ps].[lob_used_page_count] + [ps].[row_overflow_used_page_count] )
							ELSE
						( [ps].[lob_used_page_count] + [ps].[row_overflow_used_page_count] )
						END) AS [data],
					SUM ([ps].[used_page_count]) AS [used]
			FROM	[sys].[dm_db_partition_stats] [ps]
			WHERE [ps].[object_id] NOT IN ( SELECT [object_id] FROM	[sys].[tables] WHERE [is_memory_optimized] = 1 )
			GROUP BY [ps].[object_id] ) AS [a1]
	LEFT OUTER JOIN ( SELECT	[it].[parent_id], SUM ([ps].[reserved_page_count]) AS [reserved], SUM ([ps].[used_page_count]) AS [used]
					  FROM	[sys].[dm_db_partition_stats] [ps]
							INNER JOIN [sys].[internal_tables] [it] ON ( [it].[object_id] = [ps].[object_id] )
					  WHERE [it].[internal_type] IN ( 202, 204 )
					  GROUP BY [it].[parent_id] ) AS [a4] ON ( [a4].[parent_id] = [a1].[object_id] )
	INNER JOIN [sys].[all_objects] [a2] ON ( [a1].[object_id] = [a2].[object_id] )
	INNER JOIN [sys].[schemas] [a3] ON ( [a2].[schema_id] = [a3].[schema_id] )
WHERE [a2].[type] <> N'S' AND [a2].[type] <> N'IT'
ORDER BY schemaname, tablename

• All databases in the [db] list must have the same schema.
• Requires SQL 2017 and above because of STRING_AGG() function is used

;WITH [db] AS
(
	SELECT [d].[name] [DbName]
	FROM [sys].[databases] [d]
	WHERE [d].[name] LIKE 'FILTER%'
),
[tbl] AS
(
SELECT [s].[name] [SchemaName], [t].[name] [TableName], [db].[DbName],
'	SELECT ''' + [db].[DbName] + ''' DbName, ' + STRING_AGG('[' + CAST([c].[name] AS NVARCHAR(MAX)) + ']', ', ') WITHIN GROUP (ORDER BY [c].[column_id] ASC) + CHAR(13) + 
'	FROM [' + [db].[DbName] + '].[' + [s].[name] + '].[' + [t].[name] + ']' +
CASE
	WHEN LEAD([t].[name], 1) OVER(ORDER BY [t].[name]) = ISNULL([t].[name], [t].[name]) THEN CHAR(13) + CHAR(13) + '	UNION ALL' + CHAR(13) + CHAR(13)
	ELSE ''
END [Stmt]
FROM [$SCHEMA_SOURCE_DB$].[sys].[tables] [t]
	INNER JOIN [$SCHEMA_SOURCE_DB$].[sys].[schemas] [s] ON [s].[schema_id] = [t].[schema_id]
	INNER JOIN [$SCHEMA_SOURCE_DB$].[sys].[columns] [c] ON [c].[object_id] = [t].[object_id]
	CROSS JOIN [db]
GROUP BY [db].[DbName], [s].[name], [t].[name]
)
SELECT 
	[tbl].[SchemaName], [tbl].[TableName], 
	'CREATE VIEW [dbo].[v_' + [tbl].[SchemaName] + '_' + [tbl].[TableName] + ']' + CHAR(13) + 
	'AS' + CHAR(13) + 
	STRING_AGG(CAST([Stmt] AS NVARCHAR(MAX)), '') WITHIN GROUP (ORDER BY [Stmt] ASC) + CHAR(13) + 
	'GO' + 
	CHAR(13)
FROM [tbl]
GROUP BY [tbl].[SchemaName], [tbl].[TableName]
ORDER BY [tbl].[SchemaName], [tbl].[TableName]

For sure we can use this script to search for any string we are interested in.

DECLARE @ObjectName sysname
DECLARE @Command NVARCHAR(MAX)

SET @ObjectName = 'THE_OBJECT'

SET @Command = 
'IF ''?'' NOT IN(''master'', ''model'', ''msdb'', ''tempdb'') 
BEGIN 
	USE ? 

	SELECT DB_NAME()

	SELECT DB_NAME() [DbName], [o].[name] [ObjectName], [o].[type_desc] [ObjectType]
	FROM [sys].[sql_modules] [sm]
		INNER JOIN [sys].[objects] [o] ON [o].[object_id] = [sm].[object_id]
	WHERE [definition] LIKE ''%' + @ObjectName + '%'' OR [definition] LIKE ''%\[' + @ObjectName + '\]%'' ESCAPE ''\''
	ORDER BY [ObjectName]
END'

EXEC [sys].[sp_MSforeachdb] @Command
GO

Including object schema:

SELECT [rs].[name] [PKschema], [ro].[name] [PKtable], [rc].[name] [PKcolumn], [ps].[name] [FKschema], [po].[name] [FKtable], [pc].[name] [FKcolumn], [fk].[name] [FKname]
FROM [sys].[foreign_keys] [fk]
	INNER JOIN [sys].[all_objects] [po] ON [po].[object_id] = [fk].[parent_object_id]
	INNER JOIN [sys].[schemas] [ps] ON [ps].[schema_id] = [po].[schema_id]
	INNER JOIN [sys].[all_objects] [ro] ON [ro].[object_id] = [fk].[referenced_object_id]
	INNER JOIN [sys].[schemas] [rs] ON [rs].[schema_id] = [ro].[schema_id]
	INNER JOIN [sys].[foreign_key_columns] [fkc] ON [fkc].[constraint_object_id] = [fk].[object_id] AND
													[fkc].[parent_object_id] = [fk].[parent_object_id] AND
													[fkc].[referenced_object_id] = [fk].[referenced_object_id]
	INNER JOIN [sys].[columns] [pc] ON [pc].[object_id] = [fk].[parent_object_id] AND [pc].[column_id] = [fkc].[parent_column_id]
	INNER JOIN [sys].[columns] [rc] ON [rc].[object_id] = [fk].[referenced_object_id] AND [rc].[column_id] = [fkc].[referenced_column_id]
ORDER BY [ro].[name], [rc].[name], [po].[name], [pc].[name]